BwB messages

Completed patches for Keen3.
Post Reply
User avatar
levellord
Crazy pAtChEr
Posts: 1401
Joined: Thu Nov 20, 2003 11:35 pm
Location: NewZealand
Contact:

BwB messages

Post by levellord »

Here is how to patch the window et cetra for Keen 3's BwB messages. Like the Keen 1 patches, it is possible to wire the patches so that only ONE message [or twoo, or three] appear when Keen clicks the BwB, and this message[s] can be made longer to use up the extra space. You can also insert extra 'line downs' [$0A] in your message. In other words, you can totally customize the messages!

Code: Select all

#B-w-B message window width [in letters]
%patch $B86F $20 $00
#Window height [in lines of text]
%patch $B86B $06 $00

#Text read from $19820; thus first message first line is $19820 + $35E4
# = $1CE04 Thus $A7 $37 will delete a line

#First message
%patch $B88D $E4 $35
%patch $B895 $05 $36
%patch $B89D $23 $36
%patch $B8A5 $43 $36

#Second message
%patch $B8AF $58 $36
%patch $B8B7 $78 $36
%patch $B8BF $97 $36

#Third message
%patch $B8C9 $B6 $36
%patch $B8D1 $D7 $36
%patch $B8D9 $F3 $36
%patch $B8E1 $15 $37

#Fourth message
%patch $B8EB $31 $37
%patch $B8F3 $4F $37
%patch $B8FB $70 $37
%patch $B903 $8C $37

#Press a key text [complex cetering function]
#Distance from top of box [4 lines down, message *starts* with $0A = 5th line, bottom of box]
%patch $B90F $04 $00
#Read from: [Hard to change, see below]
%patch $B915 $A8 $37 #Press a
%patch $B926 $BB $37 #Key
%patch $B930 $C0 $37 #Button


#The BWB messages terminate with $00 and line down is $0A; this can alter the length
of the message lines; but not the NUMBER of lines read from. 

#BWB Message 1-4 lines
%patch $1CE04 "You enter your ship, sit around" $0A $00
%patch $1CE25 "for a while, get bored, then" $0A $00
%patch $1CE43 "remember that you have to find" $0A $00
%patch $1CE63 "the Grand Intellect!" $00

#BWB Message 2-3 lines
%patch $1CE78 "Into the ship you journey, lie" $0A $00
%patch $1CE98 "about a bit, then resume your" $0A $00
%patch $1CEB7 "quest for the Grand Intellect!" $00

#BWB Message 3-4 lines
%patch $1CED6 "You feel like entering the ship" $0A $00
%patch $1CEF7 "and taking a rest, but the" $0A $00
%patch $1CF13 "mystery of the Grand Intellect's" $0A $00
%patch $1CF35 "identity changes your mind." $00

#BWB Message 4-4 lines
%patch $1CF51 "Entering the ship might be a" $0A $00
%patch $1CF6F "fun thing to do, but right now," $0A $00
%patch $1CF90 "you need to find the Grand" $0A $00
%patch $1CFAC "Intellect and vanquish him!" $00

#Press a key message; *must* start with a $0A!
%patch $1CFC8 $0A "         press a " $00
%patch $1CFDB "key:" $00
%patch $1CFE0 "button:" $00
Some notes; firstly there is a special adress that will 'delete' a line when put into the 'text read from' This will make the line invisible. For the following patch, the second message is made into four lines using linebreaks; but only one line is used for the message, I find this makes it easier to patch the text; we also get 3 extra spaces which I use.

Code: Select all

#Second message
%patch $B8AF $58 $36
%patch $B8B7 $A7 $37 #Deleted
%patch $B8BF $A7 $37 #Deleted

#BWB Message 2-1 line for the whole window
%patch $1CE78 "Into the ship you journey," $0A
                         "lie about a bit and resume" $0A
                         "your quest for the Grand" $0A
                         "Intellect! Yay!" $00
Enjoy!
Post Reply